#!/usr/bin/gnuplot
# gnuplot 4.6 
# gnuplot script for plotting eurofxref-hist.csv as obtained from
# http://www.ecb.int/stats/exchange/eurofxref/html/index.en.html
 
# download and unzip data if not available - delete eurofxref* to force new download.
# remove or comment out these lines in Windows/MacOS.
! [ -f eurofxref-hist.csv ] || wget http://www.ecb.int/stats/eurofxref/eurofxref-hist.zip
! [ -f eurofxref-hist.csv ] || unzip eurofxref-hist.zip
 
#input
set timefmt "%Y-%m-%d"
set datafile missing "N/A"
set datafile separator ','
 
#output
set key top left
set style data lines
set grid
 
set xdata time
set xlabel 'Date'
set xrange ['1999-01-04':*]
set mxtics 4
set format x '%Y'
 
set ylabel 'Indexed exchange rates'
set format y '%g%%'
 
set term png small size 1000,600 font "Arial,10"
 
set outp 'Euro exchange rate to USD, JPY, and GBP.png'
set style line 1 lt rgb 'green' lw 1
set style line 2 lt rgb 'red' lw 1
set style line 3 lt rgb 'blue' lw 1
 
plot \
    'eurofxref-hist.csv' \
    usi 1:($2/0.011789) title '100%=1.18 USD' ls 1, \
    '' usi 1:($3/1.3373) title '100%=134 JPY' ls 2, \
    '' usi 1:($9/0.00711) title '100%=0.71 GBP' ls 3